**微算機實驗期末專題**

**姓姓名：陳達軒**

**學號：0610837**

**上課時間：**

**2018 Fall 2EF**



自走車控制

**ㄧ、Introduction：**


但請以自己對本次實驗的認知來加以說明。

利用超音波測距來測量車子與障礙物距離，藉此控制左右兩個步進馬達不同的轉速，藉此達到讓車子轉向的功能。


**二、Technical Part：**


先利用超音波馬達，測量與目標距離，若沒有目標則步進馬達固定向前，若測量到前方有目標擋住行駛，則控制步進馬達後退，然後轉向來達到回避目標的功能，不斷重複此迴路讓車子行進。

**三、Hardware Architecture：**

****

**四、Program flow chart：**

****

****

**五、Experience：**

這次的期末專題主題是由自己決定。因為不知道要做什麼，所以還是做了自動車，整個過程和以往不同，要自己靠這學期的所學來摸索，從組裝的架構到配合程式的運行，對我來說和以往照著組裝不同，是一次比較新的體驗。一開始會有車輪轉動力量不夠的情形，後來檢查後發現和delay時間有關，若是時間過短，則轉動力量會下降的很嚴重。另外程式則是結合了兩次的實驗，在delay上也得更加小心，如果delay時間過短，會導致車輪轉動力量不夠，但若如果delay時間過長，則會導致超音波無法正常收發訊號，所以時間長短的取捨必須相當小心，另外輪子位置的設計也會影響滾動的力道、超音波放置的位置等等，都必須從頭自己摸索。這次的實驗也嘗試過控制輪子的轉速來達到想要的效果，但是由於輪子本身抓地力不夠，所以其實在轉彎時測試出來只轉動其中一邊會是比較好的結果，沒有實際應用到輪子轉速的部分我覺得相當可惜。我覺得這次的專題非常有趣，能做自己選擇的東西，並且一步一步規劃和修改，也讓我了解到微算機在軟體和硬體結合的時候其實會遇到很多意想不到的困難，未來還是希望能有機會做更多類似的東西。

**六、Code and annotations：**

ORG 0000H

JMP START

ORG 000BH ;T/C0

JMP SET1

ORG 0013H ;INT1

JMP GETRESULT

ORG 0050H

START:

SETB IT1

MOV IP,#00000100B ;INT1 priority 1

MOV IE,#10000110B ;interrupt enable ,TF0,INT1,ALL

CLR P1.0

CLR TF0 ;clear timer 0 over flow flag

CLR TF1 ;clear timer 1 over flow flag

MOV TMOD,#11100010B

;GATE p3.3 gate control C1 MODE2/NOGATE T0 MODE2

MOV TH0,#227

;timer0 產生方波給counter1 clock輸入(p3.5)用

MOV TL0,#227

SETB TR0 ;TR0=1 可以由外部控制

MOV TH1,#0 ;counter1 數總共count幾次

MOV TL1,#0

SETB TR1 ;TR1=1 可以由外部控制

MOV R0,#0 ;將R0設為一個度數參考

MOV R1,#255 ;初始化預設值

MOV R2,#00010001B

MOV R3,#00010001B

MAIN:

SETB P1.1 ;設定一個方波給trigger

CALL MOVE ;移動車輛

CLR P1.1 ;結束方波

CALL MOVE ;再次移動車輛

CALL CHECK ;查看前方障礙物距離

JMP MAIN ;重新執行

MOVE:

MOV A,R2 ;讀取左輪轉動角度

MOV P0,A ;將R2轉的角度輸出到P0

RR A ;轉動角度到下一個位置

MOV R2,A ;儲存角度

MOV A,R3 ;讀取右輪轉動角度

MOV P2,A ;將R3轉的角度輸出到P2

RR A ;轉動角度到下一個位置

MOV R3,A ;儲存角度

CALL DELAY ;延遲等待轉動

INC R0 ;計數R0++

CJNE R0,#100,MOVE ;看是否轉了100次

MOV R0,#0 ;R0歸零

RET ;回歸

CHECK:

MOV A,R1 ;檢查超音波距離

SUBB A,#5 ;是否大於5

JC MOVEBACK ;是的話則跳

CLR C ;carry歸零

RET ;返回

MOVEBACK:

MOV A,R2 ;同MOVE

MOV P0,A

RL A ;輪子往後轉

MOV R2,A

MOV A,R3

MOV P2,A

RL A

MOV R3,A

CALL DELAY

INC R0

CJNE R0,#255,MOVEBACK

MOV R0,#0

CLR C

TURN:

MOV A,R3 ;只轉其中一邊的輪子

MOV P2,A

RR A

MOV R3,A

CALL DELAY

INC R0

CJNE R0,#255,TURN

MOV R0,#0

RET

SET1:

CPL P1.0 ;TF0=1

CLR TF0

RETI

GETRESULT:

;給trigger 產生echo接到P3.3當echo high時啟用counter1

MOV A,TL1

;開始接收來自timer0的clock,echo low時觸發interrupt

MOV R1,A

INITIALTC:

CLR TF1

MOV TH1,#0

MOV TL1,#0

RETI

DELAY:

MOV R6,#200

DELAY1:

MOV R7,#100

DELAY2:

DJNZ R7,DELAY2

DJNZ R6,DELAY1

RET

END